A legtöbb modern fejlesztőezköz jelentősen megkönnyíti a játékok készítését, nincs ez másként a Godot Engine esetében sem, így minimális kód hozzáadásával bírhatjuk működésre első játékunkat.

Előkészület

A játékunk annyiból fog állni, hogy elindítás után egy másodperccel kilövi a labdát valamelyik irányba, majd a játékosoknak vissza kell azt ütniük. Amint valamelyik játékos elér öt pontot, a játék kiírja, hogy ki nyert majd három másodperc múlva kezdődik elölről.

Ütők mozgatása

extends KinematicBody2D

# milyen gyorsan mozogjon az ütő (pixel/másodperc)
var sebesseg = 600

# _physics_precess(delta) fix időközönként fut le,
# így mozgáshoz érdemes ezt használni
# a "delta" biztosítja, hogy az ütő fix sebességgel mozogjon függetlenül attól,
# hogy 60 vagy 200 fps-sel fut a játék
func _physics_process(delta):
    # ha a node neve BalUto
    if name == "BalUto":
        # ha le van nyomva a gomb, amit a "bal_fel"-nek megadtunk
        if Input.is_action_pressed("bal_fel"):
            # mozduljon el az ütő felfelé, az adott sebességgel
            move_and_collide(Vector2.UP * sebesseg * delta)
		
        # ha le van nyomva a gomb, amit a "bal_le"-nek megadtunk
        if Input.is_action_pressed("bal_le"):
            # mozduljon el az ütő lefelé, az adott sebességgel
            move_and_collide(Vector2.DOWN * sebesseg * delta)

    # ha a node neve JobbUto
    if name == "JobbUto":
        # ha le van nyomva a gomb, amit a "jobb_fel"-nek megadtunk
        if Input.is_action_pressed("jobb_fel"):
        # mozduljon el az ütő felfelé, az adott sebességgel
            move_and_collide(Vector2.UP * sebesseg * delta)
		
        # ha le van nyomva a gomb, amit a "jobb_le"-nek megadtunk
        if Input.is_action_pressed("jobb_le"):
            # mozduljon el az ütő lefelé, az adott sebességgel
            move_and_collide(Vector2.DOWN * sebesseg * delta)

Labda mozgatása

extends RigidBody2D

# milyen gyorsan mozogjon a labda (pixel/másodperc)
export var sebesseg = 600


func _ready():
    # véletlenszám generátor indítása
    randomize()

    # labda középre helyezése
    global_position = Vector2(640, 360)

    # egy másodperc várakozás, majd a labda indítása
    yield(get_tree().create_timer(1.0), "timeout")
    indulj()


# labda indítása
func indulj():
    # irány megadása, mely csak 1 és -1 lehet
    # a pow(szam1, szam2) a szam1-et a szam2 hatványra emeli
    # a randi() % 2 egy véletlenszámot generál, melynek értéke 0 vagy 1 lehet
    # minden szám 0. hatványa 1, első hatvány pedig önmaga
    # így kapjuk meg a fent említett 1-et és -1-et
    var x_irany = pow(-1, randi() % 2)
    var y_irany = pow(-1, randi() % 2)
	
    # irány és sebesség megadása
    linear_velocity = Vector2(x_irany, y_irany) * sebesseg

Pontszerzés

extends Node2D

# készítünk egy hivatkozást a Kijelzo nevű node-ra
onready var Kijelzo = $Kijelzo
# előtöltjük a Labda scene-t,
# hogy játék közben új példányokat hozhassunk létre belőle
var labda_scene = preload("res://Labda.tscn")

# a játékosok pontszáma
var bal_pont = 0
var jobb_pont = 0

# a győzelemhez szükséges pontszám
# a const értéke állandó, nem változhat a játék során
const gyozelem_pont = 5


func _ready():
    # a játék kezdetekor létrehozunk egy példányt a labdából
    var Labda = labda_scene.instance()
    # ez a példány a Palya node child node-ja lesz
    add_child(Labda)


# ha a labda bekerül a bal oldali kapuba
func _on_BalKapu_body_entered(body):
    # a jobb oldali játékos kap egy pontot
    jobb_pont += 1
    # töröljük a labdát
    body.queue_free()
    # hívjuk a pont ellenörző függvényt
    pont_ellenorzes(jobb_pont, "A JOBB OLDALI JÁTÉKOS NYERT!")


# ha a labda bekerül a jobb oldali kapuba
func _on_JobbKapu_body_entered(body):
    # a bal oldali játékos kap egy pontot
    bal_pont += 1
    # töröljük a labdát
    body.queue_free()
    # hívjuk a pont ellenörző függvényt
    pont_ellenorzes(bal_pont, "A BAL OLDALI JÁTÉKOS NYERT!")


# pont ellenörző függvény
# hívásakor az "oldal_pont" és a "szoveg" helyére saját értéket adhatunk
func pont_ellenorzes(oldal_pont, szoveg):
    # a függvényhíváskor megadott saját értéket (pl.: bal_pont)
    # fogja ide behelyettesíteni
    # ha az az érték még nem éri el a győzelemhez szükséges értéket
    if oldal_pont < gyozelem_pont:
        # akkor létrehozunk egy új labda példányt
        var Labda = labda_scene.instance()
        # megvárjuk, hogy az adott frame befejeződjön,
        # majd a labda példányt a Palya-hoz adjuk child node-ként
        call_deferred("add_child", Labda)
        # frissítjük a kijelzőt az aktuális eredménnyel
        Kijelzo.text = str(bal_pont) + " - " + str(jobb_pont)
    # különben pedig
    else:
        # a kijelző szövegét arra a szövegre változtatjuk,
        # amit fent a "szoveg" helyére beírtunk függvényhíváskor
        Kijelzo.text = szoveg
        # várunk 3 másodpercet
        yield(get_tree().create_timer(3.0), "timeout")
        # majd újra betöltjük az aktuális scene-t, így új játékot indítva
        get_tree().reload_current_scene()